ホーム / 電子工作 /

【ESP32入門】ESP32とWS2812Bでオーディオレベルメーターを作る【8回目】

2023/02/04

ESP32 FFT MCP3208 WS2812B レベルメーター 電子工作

t f B! P L
レベルメータ作成のまとめはこちら

目次[非表示]

はじめに

どうもtakaです。
良き父親を目指して日々奮闘中です。ついに体重が減少に転じました。というよりやつれているだけのような・・・
さて、ESP32とWS2812Bでオーディオレベルメーター製作、ついに最終回！
主たる機能はすでにこれまで紹介しておりますので今回はそれらを組み合わせLEDの点灯パターンを決定すれば完成です！

点灯パターンをどうするか？

WS2812BはフルカラーLEDなのでフルカラーを活かしたいですそこで、次のような点灯パターンを実装しました！

・配色：FFT結果の周波数軸を3分割しRGBに割り当てる
・点灯個数：各周波数範囲で最大スペクトルを点灯個数に割り当てる

配色について

低音域:中音域:高音域=0.03:0.2:1で分割します。
具体的には
低音域（R）:中音域（G）:高音域（B）=0~450:450～3000:3000~15[kHz]です。

点灯個数について

FFT結果のスペクトルはdBmVに対数圧縮し、その結果をそのまま点灯個数に割り当てます。

例えば、0~450[Hz]のスペクトルの最大スペクトルが20[dBmV]であれば、赤色を20個点灯させます。これをRGB同時に重ねることでフルカラーを活かしています。

ウェーバー・フェヒナーの法則について

法則を要約すると人間の五感は全て対数を感じているというものです。聴覚でいうと音量が小さい領域の変化は敏感ですが、大音量領域は大して差を感じません。味覚も痛覚も同じで、刺激が小さいときほど変化を感じやすく、刺激が大きなときは変化を感じにくいという法則です。オーディオのボリュームでは抵抗が非線形カーブ(Aカーブ)の物が使用されますが、これがまさにこの法則から来ているものです。

スペクトルや周波数分割幅を対数圧縮している理由はこれにあります。リニアスケールのまま点灯させると聴覚と視覚の繋がりが悪く音に連動しているようには感じ取れません。

考えた点灯パターンで実際に点灯させてみる

実際に点灯させるとこんな感じになります。

聴覚の低中高音が直観的にRGBに配色できているように見えますか？
また、音量が直観的に点灯個数に割り当てられているように見えますか？

システムの構成

ハード

前回 の投稿をご覧ください。前回使用しなかったVR3は今回使用します。詳しくはプログラムをご覧いただくとして、VR3でLEDの減光速度を調整できるようにしています。
先述しましたがLEDの個数はスペクトルの強さです。ただ、実直に実際の音に連動させてしまうと目が追い付かずとてもせわしないです。そこでVR3の出番です。この機構は音楽ジャンルに合わせて使うこともできます。スローペースな曲では減光速度を遅くし滑らかに移り変わり、アップテンポな曲では減光速度を速めるような使い方ができます。

ソフト

main.c、MCP3208.cpp、MCP3208.hを全て同じ階層に保存しESP32に焼きこんでください。

・main.ino 
  1. #include "arduinoFFT.h"
  2. #include "MCP3208.h"
  3. #include <FastLED.h>
  4.  
  5. //--------------------------------FFT用定義--------------------------------
  6. #define SAMPLING_FREQUENCY 30000.0
  7. #define FFTSMPLES 1024
  8. double vReal[FFTSMPLES];
  9. double vImag[FFTSMPLES];
  10. arduinoFFT FFT = arduinoFFT(vReal, vImag, FFTSMPLES, SAMPLING_FREQUENCY);
  11. //------------------------------------------------------------------------
  12.  
  13. //------------------------------MCP3208用定義------------------------------
  14. #define MCP3208_VCC 5.0
  15. #define MCP3208_REF_MILLIVOLT 5000.0
  16. #define SPI_CSPIN 5
  17. #define MCP3208_ADCMAX_VAL 4095.0
  18. #define MCP3208_LCH 0
  19. #define MCP3208_LREFCH 1
  20. #define MCP3208_RCH 2
  21. #define MCP3208_RREFCH 3
  22. #define MCP3208_DIMMERCH 4
  23.  
  24. mtMCP3208 adcObj(MCP3208_VCC, SPI_CSPIN, MCP3208_REF_MILLIVOLT);
  25. //------------------------------------------------------------------------
  26.  
  27. //----------------------------LED制御用------------------------------------
  28. #define LED_PIN     16
  29. #define NUM_LEDS    60
  30. #define BRIGHTNESS  100
  31. #define LED_TYPE    WS2812B
  32. #define COLOR_ORDER GRB
  33. CRGB leds[NUM_LEDS];
  34. //-------------------------------------------------------------------------
  35.  
  36. //------------------------------電圧サンプリング-----------------------------
  37. const unsigned int sampling_period_us = 1000000.0 / SAMPLING_FREQUENCY; //サンプリング間隔[us]
  38. void sample() {
  39. 	for (int n = 0; n < FFTSMPLES; n++) {
  40. 		unsigned long t = micros();
  41. 		vReal[n] = (double)adcObj.readAdc(MCP3208_LCH);
  42. 		vImag[n] = 0;
  43. 		while ((micros() - t) < sampling_period_us) ;
  44. 	}
  45. }
  46. //------------------------------------------------------------------------
  47.  
  48. //--------------------------------FFT実行---------------------------------
  49. void calcFFT() {
  50. 	FFT.Windowing(FFT_WIN_TYP_HAMMING, FFT_FORWARD);	// 窓関数
  51. 	FFT.Compute(FFT_FORWARD);	// FFT処理(複素数で計算)
  52. 	FFT.ComplexToMagnitude();	// 複素数を実数に変換
  53. }
  54. //------------------------------------------------------------------------
  55. //----------------------------その他サポート関数-----------------------------
  56. //DC成分を削除する
  57. void dcOmit() {
  58. 	double mean = 0;
  59. 	for (int i = 0; i < FFTSMPLES; i++) {
  60. 		mean += vReal[i];
  61. 	}
  62. 	mean /= FFTSMPLES;
  63.  
  64. 	for (int i = 0; i < FFTSMPLES; i++) {
  65. 		vReal[i] -= mean;
  66. 	}
  67. }
  68.  
  69. //FFT結果をデシベル変換する。単位は[dBmV]。
  70. void fft2dBmV() {
  71. 	for (int n = 0; n < FFTSMPLES / 2; n++) {
  72. 		vReal[n] = vReal[n] * 4.0 / FFTSMPLES;	//これでAD変換のスケールに戻る（0～4095）
  73. 		vReal[n] = vReal[n] * MCP3208_REF_MILLIVOLT / MCP3208_ADCMAX_VAL;	//これで電圧値[mV]に戻る。
  74. 		vReal[n] = 20.0 * log10(vReal[n]);
  75. 		vReal[n] = isinf(vReal[n]) ? 0.0 : vReal[n];
  76. 	}
  77. }
  78.  
  79. //FFT結果にフィルタをかける
  80. void filterFFTres() {
  81. 	//とりあえず低周波領域は精度が悪いためスペクトルを捨てる
  82. 	for (int n = 0; n < 4; n++) {
  83. 		vReal[n] = 0.0;
  84. 	}
  85. }
  86.  
  87. //FFT結果をシリアルモニタに表示する。
  88. void dispFFTres() {
  89. 	double dFrq = SAMPLING_FREQUENCY / FFTSMPLES;
  90.  
  91. 	for (int n = 0; n < FFTSMPLES / 2; n++) {
  92. 		double frq = (double)n * dFrq;
  93. 		double spc = vReal[n];
  94.  
  95. 		Serial.printf("%.0f[Hz] : %.3f[dBmV]¥n", frq, spc);
  96. 	}
  97. 	Serial.println();
  98. }
  99. //********************************点灯パターン１********************************
  100. //今回はRGBをそれぞれ低音/中音/高音の3に割り当て、点灯させるLEDの個数をスペクトル強度にする。
  101. //FFT結果の周波数軸(=要素数)を3分割しそれぞれの領域の最大スペクトル値を取得する
  102. const uint8_t LOW_FRQ_INDEX = 0;
  103. const uint8_t MID_FRQ_INDEX = 1;
  104. const uint8_t HI_FRQ_INDEX = 2;
  105.  
  106. void getMaxSpec(int *maxSpec) {
  107. 	int fftResSmaples = FFTSMPLES / 2;
  108. 	int maxBuf[3] = {0};
  109.  
  110. 	for (int n = 0; n < fftResSmaples; n++) {
  111. 		//FFT結果のデシベルがそのままLEDの点灯個数になるので負のデシベル(とても小さな電圧)は0にしておく
  112. 		vReal[n] = vReal[n] < 0 ? 0.0 : vReal[n];
  113.  
  114. 		//最大値もLEDの個数でカットする
  115. 		vReal[n] = vReal[n] > NUM_LEDS ? NUM_LEDS : vReal[n];
  116.  
  117. 		//解析結果の周波数を三等分(RGB)して各帯域の最大値を取得する
  118. 		//横軸も対数化する。今回は簡易的に三分割の方法を0.03:0.2:1で分割してみる
  119. 		if (n < fftResSmaples * 0.03) {
  120. 			maxBuf[LOW_FRQ_INDEX] = maxBuf[LOW_FRQ_INDEX] > vReal[n] ? maxBuf[LOW_FRQ_INDEX] : (int)vReal[n];
  121. 			//Serial.printf("maxBuf:%d,vReal:%f = %d¥n",maxBuf[LOW_FRQ_INDEX] ,vReal[n],maxBuf[LOW_FRQ_INDEX] > vReal[n] ? maxBuf[LOW_FRQ_INDEX] : (int)vReal[n]);
  122. 		} else if (n < fftResSmaples * 0.2) {
  123. 			maxBuf[MID_FRQ_INDEX] = maxBuf[MID_FRQ_INDEX] > vReal[n] ? maxBuf[MID_FRQ_INDEX] : (int)vReal[n];
  124. 		} else {
  125. 			maxBuf[HI_FRQ_INDEX] = maxBuf[HI_FRQ_INDEX] > vReal[n] ? maxBuf[HI_FRQ_INDEX] : (int)vReal[n];
  126. 		}
  127. 	}
  128.  
  129. 	*maxSpec=maxBuf[LOW_FRQ_INDEX];
  130. 	*(maxSpec+1)=maxBuf[MID_FRQ_INDEX];
  131. 	*(maxSpec+2)=maxBuf[HI_FRQ_INDEX];
  132. 	
  133. }
  134. //減光速度をボリュームで調整する処理
  135. int decLed = 70;	//減光スピード。この関数を1回呼び出し前回より点灯個数が少なくなる場合は、すぐに消灯せず照度をこの値だけ減光する
  136. 						//ジャズのようなスローテンポなら35くらい
  137. 						//ポップなら70位か？
  138. void setDimmer(){
  139. 	int dimmerLevel=adcObj.readAdc(MCP3208_DIMMERCH);
  140. 	decLed = 255.0*dimmerLevel/MCP3208_ADCMAX_VAL;
  141. }
  142.  
  143. //getMaxSpecでLED点灯個数が決定したので、照度と色の情報に変換していく
  144.  
  145. void genColorArray(int *maxSpec) {
  146. 	static int ledColor[3][NUM_LEDS]={0};
  147. 		
  148. 	for (int rgbCnt = 0; rgbCnt < 3; rgbCnt++) {
  149. 		for (int n = 0; n < NUM_LEDS; n++) {
  150. 			if (n <= *(maxSpec+rgbCnt)) {			//nがスペクトル（個数相当）未満なら照度MAX（255）で点灯
  151. 				ledColor[rgbCnt][n] = 255;
  152. 			} else if (ledColor[rgbCnt][n] - decLed > 0) {
  153. 				ledColor[rgbCnt][n] -= decLed;
  154. 			} else {
  155. 				ledColor[rgbCnt][n] = 0;
  156. 			}
  157. 		}
  158. 	}
  159.  
  160. 	const uint8_t lowFrqIndex=0 , midFrqIndex=1 , hiFrqIndex=2;
  161. 	
  162. 	//RGB毎に点灯個数を決定したのでRGB情報に変換する
  163. 	for (int n = 0; n < NUM_LEDS; n++) {
  164. 		leds[n] = CRGB( ledColor[lowFrqIndex][n], ledColor[midFrqIndex][n], ledColor[hiFrqIndex][n]);
  165. 	}
  166. }
  167. //------------------------------------------------------------------------
  168. void setup() {
  169. 	Serial.begin(115200);
  170. 	delay(3000);
  171.  
  172. 	//AD変換の初期化
  173. 	adcObj.adcInit();
  174.  
  175. 	//FastLEDの初期化
  176. 	FastLED.addLeds<LED_TYPE, LED_PIN, COLOR_ORDER>(leds, NUM_LEDS).setCorrection( TypicalLEDStrip );
  177. 	FastLED.setBrightness(BRIGHTNESS);
  178. 	FastLED.clear();
  179. }
  180. void loop() {
  181. 	sample();		//SAMPLING_FREQUENCYでFFTSMPLES回サンプリング実施
  182. 	dcOmit();		//直流成分の除去
  183. 	calcFFT();		//FFT実施
  184. 	filterFFTres();	//低周波側の端っこ数要素は精度が怪しいので捨てる。
  185. 	fft2dBmV();		//FFT結果をdBmVへ変換する
  186. 	
  187. 	//dispFFTres();	//デバッグ用
  188. 	
  189. 	//------LED制御------
  190. 	int maxSpec[3] = {0};
  191. 	setDimmer();		//減光速度を可変抵抗から読み取る
  192. 	//Serial.println(decLed);
  193. 	getMaxSpec(maxSpec);	//FFT結果（周波数軸)を3分割し各領域の最大スペクトル値を取得する
  194. 	//Serial.printf("low:%d,mid:%d,hi:%d¥n",maxSpec[0],maxSpec[1],maxSpec[2]);
  195. 	genColorArray(maxSpec);	//最大スペクトルに応じたLED点灯用配列に格納する。
  196. 	FastLED.show();
  197. 	
  198. 	//デバッグ用
  199. 	//Serial.println(adcObj.readAdc(MCP3208_LCH));
  200. 	
  201. 	//delay(1000);
  202. }
  203.  
  204.
・MCP3208.cpp 
  1. #include <Arduino.h>
  2. #include <SPI.h>
  3. #include "MCP3208.h"
  4.  
  5. mtMCP3208::mtMCP3208(uint8_t vcc,uint8_t csPinNo,int refMilliVolt){
  6. 	this->vcc=vcc;
  7. 	this->csPinNo=csPinNo;
  8. 	this->refMilliVolt=refMilliVolt;
  9. }
  10.  
  11. void mtMCP3208::adcInit() const{
  12. 	//SPI設定
  13. 	SPI.begin();				//SPIを行う為の初期化
  14. 	SPI.setBitOrder(MSBFIRST);	//bitオーダー
  15. 	SPI.setDataMode(SPI_MODE0);
  16. 	SPI.setFrequency(vcc == 5 ? 2000000 : 1000000);	//MCP3208が5Vの時は最速の2MHzで通信できる
  17. 	pinMode(csPinNo, OUTPUT) ;
  18. 	digitalWrite(csPinNo, HIGH) ;
  19. }
  20.  
  21. int mtMCP3208::readAdc(uint8_t channel)const{
  22. 	int d1 , d2 ;
  23.  
  24. 	// ADCから指定チャンネルのデータを読み出す
  25. 	digitalWrite(csPinNo, LOW) ;
  26. 	SPI.transfer(0x06 | (channel >> 2) ) ;
  27. 	d1 = SPI.transfer( (channel & 0x03) << 6 ) ;
  28. 	d2 = SPI.transfer(0x00) ;
  29. 	digitalWrite(csPinNo, HIGH) ;
  30. 	return ((d1 & 0x0F) << 8 | d2) ;
  31. }
  32.  
  33. int mtMCP3208::readMilliVolt(uint8_t channel)const{
  34. 	int adcRes=readAdc(channel);
  35. 	return refMilliVolt*adcRes/4095.0;
  36. }
  37.  
  38.
・MCP3208.h 
  1. class mtMCP3208{
  2. 	private:
  3. 		uint8_t csPinNo;
  4. 		uint8_t vcc;
  5. 		int adcRes;
  6. 		int refMilliVolt;
  7. 		int offsetMillVolt;
  8. 		
  9. 	public:
  10. 		mtMCP3208(uint8_t,uint8_t,int);
  11. 		void adcInit()const;
  12. 		int readAdc(uint8_t)const;
  13. 		int readMilliVolt(uint8_t)const;
  14. };
  15.  
  16.
うまく動作しましたか？
ソースコードの詳細はコード中のコメントを参照ください。
若干カット&トライで作成したこともありスパゲティー気味です。ご了承を・・・

最終回は以上です。
入門編ということでかなりかみ砕き説明した部分もありボリューミーになってしまいましたが最後までご覧いただきありがとうございました！


全投稿のまとめページは こちら

中の人

自分の写真
モノ作りが好きです。GUIアプリの作成からアナログ回路まで手当たり次第です。 アンプの修理を紹介するためにブログを始めました。 （Twitter：@TakaElc）

記事カテゴリ

5M21 (10) A-6 (5) A-717 (2) A-8 (4) A-950 (1) AB級 (8) Arduino (2) A級 (29) C-21 (1) C29 (1) ESP32 (9) EUMIG (13) FFT (2) HOW2 (6) LED (2) LUXMAN (10) M-1000 (13) M-22 (23) MATLAB (1) mcintosh (1) MCP3208 (3) OPアンプ (1) Pioneer (26) QUAD (1) Simulink (1) WS2812B (4) YAMAHA (10) アンプ (62) スピーカ (3) プリ (1) プリアンプ (1) プリメイン (10) レベルメーター (8) 化石 (1) 山水 (3) 自作アンプ (7) 電子工作 (24) 日記 (1)

QooQ